;redcode-94
;name SoLT
;strategy Switch on loss or tie.
;assert CORESIZE == 8000

        org     think

; *** P-brain

think   ldp.ab  #100, switch
pmod    ldp.a   2, 2            ; just to save one instruction..
        mod.f   pmod, @think
switch  sne.a   >0, 0
        stp.ba  switch, think
        djn.b   strat2, @think

; *** TimeScape by Juha Pohjalainen

TSTEP equ 1800
CSTEP equ 3740
NSTEP equ -1922
FSTEP equ 1870

strat1  spl     1,              <-200
        spl     1,              <-300
        mov.i   -1,             0

tim1    spl     @tim1,          }TSTEP
        mov.i   }tim1,          >tim1
cel1    spl     @cel1,          }CSTEP
        mov.i   }cel1,          >cel1
        mov.i   {-FSTEP,        <FSTEP
        mov.i   {cel1,          <ncl1
ncl1    jmp     @ncl1,          >NSTEP

        dat     0, 0
        dat     0, 0

; *** Carbonite by Ian Sutton

dbomb   dat     >-1, >1
strat2  spl     #0, <-100
        mov     dbomb, tar-197*3500
tar     add     #197, -1        ; gets bombed to start coreclear
        djn.f   -2, <-1151

        end